;:remopen2,8,2,"cursor-lock,p,w
;:sys36864
	;.opt oo
	*= 50505
; cursor-lock sperrt cursortasten
; autor - nikolaus heusler 11.91
;
	lda #55
	sta 1	;rom einblenden
	lda #160
	jsr copy	;basic kopieren
	lda #224
	jsr copy	;kernal kopieren
	ldx #2
	stx 3
	stx 5
	lda #-1	;flag fuer 'taste nicht belegt'
; modifikationen am 'rom' vornehmen
	sta $ebc0
	sta $ec01
	sta $ec42	;run/stop
	sta $eb88
	sta $ebc9
	sta $ec0a	;crsr up/dwn
	sta $ebc2
	sta $ec03	;insert
	sta $ebb4
	sta $ebf5
	sta $ec36	;clr/home
	lda #201
	sta $f6da	;run stop entmachten
	lda #0	;bei input doppel-
	sta $ac6c	;punkte und kommas
	sta $ac70	;uebernehmen
	lda #76	;jump
	sta $a560
	lda #<linein
	ldy #>linein
	sta $a561
	sty $a562
	lda #76	;jump
	sta $eb3c
	lda #<here1
	ldy #>here1
	sta $eb3d
	sty $eb3e
	lda #53	;von rom auf ram
	sta 1	;umschalten
	lda #0
	sta spa1	;linker rand
	rts
spa1	brk
; copy kopiert ein rom (8 kb) in das ram
copy	ldx #32	;32 pages
	sta 3	;highbyte
	ldy #0
	sty 2
cl	lda (2),y
	sta (2),y
	iny
	bne cl
	inc 3
	dex	;naechste page
	bne cl
	rts
here1	cmp #20
	beq lef
	cmp #"\x9d"
	beq lef
	ldx 211
	cpx #39
	bcc ok
	bcs links
fault	lda #0
ok	ldx $c6
ok2	sta $277,x
	jmp $eb3f
lef	ldx 211
	cpx spa1
	beq fault
	bcc fault
	bne ok
linein	lda 211
	sta spa1
	ldx #0
loop	jsr $e112
	cmp #13
	beq ret
	sta $200,x
	inx
	cpx #$59
	bcc loop
	jmp $a571
ret	jmp $aaca
links	pha
	ldx $c6
	lda #"\x9d"
	sta $277,x
	inx
	pla
	bne ok2